Julia で統計解析　第 6 章　数値データの可視化

Version()

最新バージョン 2024-10-29 14:05

using Plots
default(
    titlefont         = (12, "times"),
    guidefont         = (10, "times"),
    tickfont          = (7, "times"),
    label             = "",
    foreground_color_legend = nothing,
    markerstrokewidth = 0,
    grid              = false,
    tick_direction    = :out,
    alpha             = 0.4
    )

1 変量のグラフ表示には，ヒストグラム（histogram）が代表的なものである。

2 変量のグラフ表示では散布図が主なものである。

Julia でグラフ表示をする場合，Plots パッケージを使用する。バックエンドは GR を使用することにする。

using Plots
gr()

Plots.GRBackend()

連続変数（数値）データとしては，R が用意しているデータセットのうちの airquality データセットを用いて例示する。

using RCall
airquality = rcopy(R"airquality");
println("size: ", size(airquality))
first(airquality, 5)

size: (153, 6)

5×6 DataFrame

Row	Ozone	Solar_R	Wind	Temp	Month	Day
	Int64?	Int64?	Float64	Int64	Int64	Int64
1	41	190	7.4	67	5	1
2	36	118	8.0	72	5	2
3	12	149	12.6	74	5	3
4	18	313	11.5	62	5	4
5	missing	missing	14.3	56	5	5

Ozone, Solar_R は欠損値を含むので取り扱いに注意が必要である。

ヒストグラム

ヒストグラムは，連続変数の分布状況を把握するのに役立つ。

一標本の場合

欠損値を含む場合，skipmissing() ではなく，filter(!ismissing,...) を使わなければならない。

x = filter(!ismissing, airquality.Ozone)
histogram(x)

特に何も指定しないと，不適切なグラフしか得られない。

最初から histogram() に引数を与えればよいが，Julia では，一度描かれたグラフに後から関数により，様々な要素を加えていくこともできる。

関数名の最後が ! であることに注意しよう。

xlabel!("Ozone")

ylabel!("Density")
title!("Histgram of Ozone")

同じ関数で内容を変更することもできる。

xlabel!("Ozone (ppb)")

direction=:horizontal を指定すれば水平ヒストグラムになる。

histogram(x, direction=:horizontal)

ヒストグラムを描く際の階級（bin とも呼ばれる）の指定法は何通りかある。

1. 階級数を整数で指定する
2. ベクトル
3. シンボル（:auto (Freedman-Diaconis), :sturges, :sqrt, :rice, :scott, :fd）

デフォルトの設定は多くの場合，適切でないことが多い。

以下の 6 個のグラフのうち，データの分布状況を最も適切に表しているのは fig.5 である。bins はベクトルで指定した。0:10:maximum(x) は最も左の階級の始まりの値が 0，階級幅が 10，最後の階級は最大値までを表している。

階級数で指定しても，そのとおりの階級数にはならないことがある。fig.4 は bins=15 を指定して描いたが実際の階級数は 9 になり，bins=10 で描いた fig.3 と同じになった。

多くの場合，ベクトルで指定するのが最もよい。

最終的な階級数が fig.2 のように少なくても，fig.6 のように多くてもデータの分布状況を正しく把握できないので何通りかやってみるとよい。

using Plots.PlotMeasures # 余白の単位 mm などを有効にするために必要

p1 = histogram(x, title="fig.1"); # bins=:auto, 
p2 = histogram(x, bins=5, title="fig.2");
p3 = histogram(x, bins=10, title="fig.3");
p4 = histogram(x, bins=15, title="fig.4");
p5 = histogram(x, bins=0:10:maximum(x), title="fig.5");
p6 = histogram(x, bins=0:5:maximum(x), title="fig.6");

plot(p1, p2, p3, p4, p5, p6, layout=(2, 3), bottom_margin = 20px)

histogram() のパラメータ normalize は縦軸の単位を変える。

• :none
  正規化しない（デフォルト）。高さは度数を表す。
• :pdf
  総面積が 1 になるように正規化する。高さは「度数/(100×階級幅)」
• :probability
bin の高さの和が 1 になるように正規化する。高さは「度数/サンプルサイズ」つまり相対度数で，100 倍すればパーセントである。
• :density
bin の面積の和が 1 になるように正規化する。階級幅が等しくない場合に適している。階級幅が等しい場合は「度数/階級幅」である。

using Plots.PlotMeasures # 余白の単位 mm などを有効にするために必要

p1 = histogram(x, normalize=:none, bins=0:10:150, title="fig.a"); 
p2 = histogram(x, normalize=:pdf, bins=0:10:150, title="fig.b");
p3 = histogram(x, normalize=:probability, bins=0:10:150, title="fig.c");
p4 = histogram(x, normalize=:density, bins=vcat(0:10:100, 125, 150...), title="fig.d");

plot(p1, p2, p3, p4, layout=(2, 2), bottom_margin = 20px)

複数標本の場合

Plots パッケージの histogram() では，複数標本のヒストグラムは重ね合わせ表示しかできないので，標本数が多い場合は不適切であろう。

欠損値を除いて月別の Ozone 測定値データセットを作る。

using DataFrames
ozone = dropmissing(select(airquality, [:Ozone, :Month]));
monthly = groupby(ozone, :Month);

using StatsPlots
histogram([monthly[i].Ozone for i in 1:2],
    bins=0:10:130,
    bar_position=:overlay,
    )

このような場合にも，前節のようなサブプロットを描く方法を使うことはできる。

using Dates # 月の英名
using Plots.PlotMeasures # 余白の単位 mm などを有効にするために必要

subplots = Array{Any, 1}(undef, 5)
for i in 1:5
    subplots[i] = histogram([monthly[i].Ozone ],
        bins=0:10:150,
        xlabel="Ozone(ppb)",
        ylabel="Days",
        title="$(monthname(i+4))",
        )
end
plot(subplots[1], subplots[2], subplots[3], subplots[4], subplots[5],
     bottom_margin = 20px)

StatsPlots パッケージの groupedhist() は，bar_position=:dodge でグループ化されたヒストグラム，bar_position=:stack で積み上げヒストグラムを描くことができる。

なお，欠損値がある場合には事前に除去処理をしておかなければならない。

指定できるキーワード引数は histogram() とほぼ同じである。bins，normed，weights，nbins，edges，bar_width

using StatsPlots

ozone = dropmissing(select(airquality, [:Ozone, :Month]));
@df ozone groupedhist(:Ozone, group=:Month, bar_position=:dodge, xlabel="Ozone")

@df airquality groupedhist(:Wind, group=:Month, bar_position=:stack,
    xlabel="Wind")

@df airquality groupedhist(:Wind, group=:Month, bar_position=:stack)

ボックスプロット（箱ひげ図）

ボックスプロットは別名ボックスアンドウィスカー（箱ひげ図）ともいわれる，下図に示すような図である。中央部の青で塗った長方形（箱）の下辺が「下ヒンジ（第 1 四分位数） $Q_1$，上辺が上ヒンジ（第 3 四分位数）$Q_3$，長方形の中ほどにある直線が中央値 $Q_2$ である。上下に伸びる T字/逆T字のようなもの（ひげ）の横棒部分は「$Q_1 - 1.5IRQ$」より大きい最小のデータ点，「$Q_3 + 1.5IRQ$」より小さい最大のデータ点である。$IRQ$ は四分範囲 = $Q_3 - Q_1$ である。ひげの更に外側に表示される点は，外れ値である。

boxplot() のパラメータは，以下の通り。

• notch
  　論理値 true/false で指定。ボックスプロットに切れ込み（ノッチ）をつけるときに true を指定する（デフォルトは false）。
• whisker_range
  　実数で指定。ひげを描くときに使われる $IQR$ の倍数（デフォルトは 1.5）。この範囲外のデータ点は外れ値である。
• outliers
  　論理値 true/false で指定。外れ値を描画するときは true（デフォルトは true）。
• whisker_width
  　実数値/シンボルで指定。ひげの横棒の長さ。箱の幅と同じならば :match，半分なら :half（デフォルトは :half）。

function fivenum!(x)
  sort!(x)
  n = length(x)
  n4 = floor(Int, (n + 3) / 2) / 2
  d = [n4, (n + 1) / 2, n + 1 - n4]
  @. 0.5 * (x[floor(Int, d)] + x[ceil(Int, d)])
end

x = filter(!ismissing, airquality.Ozone);
# q1, median, q3 = quantile(x, [0.25, 0.5, 0.75])
q1, median, q3 = fivenum!(x) # q1, q3 は「ヒンジ」なので正確にはこちらを使う
IQR = q3 - q1
top    = maximum(x[x .<= (q3+1.5IQR)])
bottom = minimum(x[x .>= (q1-1.5IQR)])
println("bottom = $bottom, q1 = $q1, median = $median, q3 = $q3, top = $top")

bottom = 1, q1 = 18.0, median = 31.5, q3 = 63.5, top = 122

using Plots
using Statistics
using StatsPlots
boxplot(x,
    xticks=:none,
    xlimit=(0.5, 1.8),
    size=(300, 300))
annotate!(
    (1.5, top,    text("top",    :left, :vcenter, 8)),
    (1.5, q3,     text("q3",     :left, :vcenter, 8)),
    (1.5, median, text("median", :left, :vcenter, 8)),
    (1.5, q1,     text("q1",     :left, :vcenter, 8)),
    (1.5, bottom, text("bottom", :left, :vcenter, 8)),
    )

WARNING: using Statistics.median in module Main conflicts with an existing identifier.

ボックスプロットは表示される図の情報量が少ないので，一標本データに使われることは少ない。多くの場合は，複数標本のデータの分布の違いを示すために使われる。

StatsPlots パッケージの groupedboxplot() も欠損値のあるデータは事前に除去しておかなければならない。

using StatsPlots
ozone = dropmissing(select(airquality, [:Ozone, :Month]))
@df ozone groupedboxplot(:Month, :Ozone)

@df airquality groupedboxplot(:Month, :Wind)

バイオリンプロット

ボックスプロットは，第 1 四分位数，中央値，第 3 四分位数と，外れ値の境界値（四分位数±$1.5 IQR$）しか表示しない。

バイオリンプロットは，デンシティープロット（カーネル密度推定値）を表示するので，データの分布状況をより詳細に表示することができる。

分布図があたかもバイオリンなどの西洋弦楽器に似ているのでバイオリンプロットと呼ばれるが，日本人的には土器のシルエットのようにも見えるであろうか。

@df airquality violin(string.(:Month), :Wind, linewidth=0)

分布の片側だけ表示することもできる（side=:right/:left）ので，それを選べばデンシティープロットに見えてくるであろう。

@df airquality violin(string.(:Month), :Wind, side=:right, linewidth=0)

ドットプロット

@df airquality dotplot(string.(:Month), :Wind, linewidth=0)

@df airquality dotplot(string.(:Month), :Wind, side=:right, linewidth=0)

このドットプロットでは，データ点が重ならないようにランダムな数値（Jitter）を加えているので，その並びに何らかの意味がありそうに見えてしまう。Python の seaborn にある swarmplot() を Julia から使えるようになっているが，これも同じ特質を持っている。

そのようなことを避けるために
https://blog.goo.ne.jp/r-de-r/e/237f8bdfda925c5d724604aa9eabc8e3
にプログラムを呈示している。

using FreqTables, Plots

function simple_dotplot(x, y; accu=0, stp=0, logflag=false, simple=false,
            symmetrical=true, sizew=600, sizeh=400)
    function logaxis(z)
        pos = zeros(100)
        minval = minimum(z)
        maxval = maximum(z)
        logmaxval = log10(maxval)
        logminval = log10(minval)
        width = logmaxval - logminval
        factor = logmaxval < 3.5 ? 15 : 8
        w = width / factor
        st = floor(logminval)
        delta = 10^st
        ic = 0
        while true
            for i = 1:9
                v = i * delta
                if minval - delta <= v <= maxval + delta
                    if (i == 1 || ic == 0) || (ic > 0 && log10(v) - pos[ic] > w)
                        if i == 1 && ic > 0 && log10(v) - pos[ic] <= w
                            ic -= 1
                        end
                        ic += 1
                        pos[ic] = log10(v)
                        prev = v
                    end
                end
            end
            delta *= 10
            if delta > maxval
                break
            end
        end
        return ic > 3 ? pos[2:ic-1] : [logminval, median([logminval, logmaxval]), logmaxval]
    end
    if logflag == true
        y0 = y
        y = log10.(y);
    end
    minx = minimum(y)
    maxx = maximum(y)
    rng = maxx - minx
    minx = minx - rng * 20 / sizeh
    maxx = maxx + rng * 20 / sizeh
    if accu == 0
        accu = (maxx - minx) / 50
    end
    if stp == 0
        stp = 30 / sizew
    end
    y = round.(y ./ accu, digits=0) * accu
    table = freqtable(y, x)
    yname, xname = names(table)
    nvalue, ngroup = size(table)
    # pyplot()
    p = plot(tick_direction=:out, xticks=false, grid=false,
                size=(sizew, sizeh), xlims = (0, length(xname)+1),
                ylims=(minx, maxx), label="")
    xticks!(1:ngroup, xname)
    for i = 1:ngroup
        for j = 1:nvalue
            if table[j, i] != 0
                n = table[j, i]
                if n == 1
                    height, position = [yname[j]], [i]
                else
                    height = repeat([yname[j]], n)
                    position = collect(range(i-stp*(n-1)/2, i+stp*(n-1)/2, length=n))
                end
                p = scatter!(position, height, labels="", alpha=0.7,
                                markercolor=i, markerstrokecolor=i)
            end
        end
    end
    if logflag
        pos = logaxis(y0)
        yticks!(pos, string.(round.(10 .^ pos, digits = 1)))
    end
    println("accu = $accu, stp = $stp")
    # display(p)
    p
end;

x = string.(airquality.Month); # 型変換が必要
y = airquality.Wind;
simple_dotplot(x, y, accu=0.105, stp=0.05)

accu = 0.105, stp = 0.05

カーネル密度推定の描画

一標本データの分布に限らず複数標本のデータの分布の違いを表示するのに適している。

density() は事前に missing 処理をしておかなければならない。

using StatsPlots
x = dropmissing(select(airquality, [:Ozone, :Month]))
@df x density(:Ozone, group = :Month)
xlabel!("Ozone")
ylabel!("Density")

using Dates
airquality.Monthname = monthname.(airquality.Month)
@df airquality density(:Wind, group = :Monthname)
xlabel!("Wind")
ylabel!("Density")

$Q-Q$ プロット

$Q-Q$ プロットは，データの分布が正規分布かどうかを確認するために用いられる。

qqnorm() は前もって欠損値を除去しておかねばならない。また，引数は実数ベクトルでなければならないので float() で実数化しておかねばならない。

qqline=:R を指定すると，R でのデフォルトに從う（描く直線が分布の $Q_1$, $Q_3$ を通る）。

x = float.(filter(!ismissing, airquality.Solar_R))
qqnorm(x)
qqnorm!(x, qqline=:R)
annotate!(330, 400, text("default", :blue, "times", 8))
annotate!(380, 360, text(":R", :green, "times", 8))

using Plots.PlotMeasures # 余白の単位 mm などを有効にするために必要")
using Distributions
p1 = qqnorm(airquality.Wind, title="p1")
p2 = qqplot(Normal, airquality.Wind, title="p2"); # qqnorm() と同じ
p3 = qqnorm(airquality.Wind, qqline=:R, title="p3"); # R と同じ
p4 = qqplot(Cauchy, airquality.Wind, title="p4"); # 第 1 引数で分布を指定できる
plot(p1, p2, p3, p4, bottom_margin = 20px) #   サブプロットのボトムの余白 xxpx)

WARNING: using Distributions.median in module Main conflicts with an existing identifier.

散布図

散布図は，2 変数の分布状況を表示するのに最適の方法である。

scatter() は，欠損値 missing を自動的に除く。

scatter(airquality.Ozone, airquality.Solar_R)
xlabel!("Ozone (ppb)")
ylabel!("Solar Radiation (lang)")

scatter() のオプションで，smooth=true とすることで回帰直線を記入できる。

scatter(airquality.Wind, airquality.Temp, smooth=true)
xlabel!("Wind (mph)")
ylabel!("Temperature (degrees F)")

グループ別に色やマーカーを変えるには，

markercolor  整数値, :red, :blue, :green, :brown, :black, :cyan, :magenta, ...
http://juliagraphics.github.io/Colors.jl/stable/namedcolors/
markershape  :none, :auto, :circle, :rect, :star5, :diamond, :+, :x,
:hexagon, :cross, :xcross, :utriangle, :dtriangle, :rtriangle, ...
https://docs.juliaplots.org/latest/generated/attributes_series/
markersize   整数値（デフォルトは 4 ピクセル）

color2  = [:red, :blue, :cyan, :brown, :pink];
marker2 = [:circle, :rect, :star5, :diamond, :hexagon];

using Dates
p = scatter(airquality.Ozone, airquality.Solar_R,
    markercolor=color2[airquality.Month.-4],
    markershape=marker2[airquality.Month.-4],
    xlims=(0, 170),
    xlabel="Ozone",
    ylabel="Solar_R",
    label="")
for i in 1:5
    scatter!([100], [120-20i], markercolor=color2[i], markershape=marker2[i], label="")
    annotate!(105, 120-20i, text("$(monthname(i+4))", :left, 8), label=""); 
end
p

カーネル密度推定

変数のカーネル密度関数を推定する。

marginalkde() は，等高線と図の本体上部と右にそれぞれの変数の周辺分布のカーネル密度を描く。

欠損値を含む場合はリストワイズ除去したデータフレームを使うか，描画する 2 変数でペアワイズ除去して使用する。

using StatsPlots
df = dropmissing(select(airquality, [:Ozone, :Solar_R]))
marginalkde(df.Ozone, df.Solar_R)

┌ Warning: Keyword argument `orientation` is deprecated.
│ Please use `permute` instead.
└ @ Plots ~/.julia/packages/Plots/kLeqV/src/args.jl:1552

missing をペアワイズ除去したデータフレームの作り方は何通りかある。

また，marginalkde() に引き続いて他のプロット関数を使用することもできる。以下の図は，scatter!() によりデータ点を追加した例である（scatter() ではなく，scatter!() にしなければならない）。subplot=2 は描画対象が図の本体部分であることを示す。smooth=true により，回帰直線を描画する。

using StatsPlots
df2 = dropmissing(DataFrame(x = airquality.Ozone, y = airquality.Solar_R))
marginalkde(df2.x, df2.y)
scatter!(df2.x, df2.y, subplot=2, smooth=true, linecolor=:black)

散布図行列

散布図行列は，複数の変数間の散布図を行列状に配置する。いくつかの関数がありそれぞれ特徴を持っている。

ヒストグラムにおける「1.2.3. 複数のグラフを行列状にまとめて表示する方法」を応用して，自分で描画することもできる。

欠損値は事前に除いておかなければならない。dropmissing() で欠損値をリストワイズ除去し，corrplot() で使用する変数を指定する。

corrplot() の第 1 引数は $1×k$ 行列である（すなわち，要素をカンマではなく空白で区切る）。

各図の $x$ 軸，$y$ 軸ラベルは，デフォルトでデータフレームの列名が使用される。別の名前にしたいときは，remane!()/rename() で列名を変更しておくか，直接 label=["a" "b" "c" "d"] のように名前を空白で区切って指定すればよい。

using DataFrames
using StatsPlots
using RCall
airquality = rcopy(R"airquality")
first(airquality, 3)

3×6 DataFrame

Row	Ozone	Solar_R	Wind	Temp	Month	Day
	Int64?	Int64?	Float64	Int64	Int64	Int64
1	41	190	7.4	67	5	1
2	36	118	8.0	72	5	2
3	12	149	12.6	74	5	3

airquality2 = dropmissing(airquality)
@df airquality2 corrplot([:Ozone :Solar_R :Wind :Temp], markersize=3, size=(600, 600))

cornerplot() は各変数のヒストグラムは，本体の図の上と右に描画される。

欠損値は事前に除いておかなければならない。select() で変数を指定して，dropmissing() で missing をリストワイズ除去したデータフレームを作る。

cornerplot() の第 1 引数はデータフレームではなく行列でなけれbならないので，Matrix() で行列として指定する。

各図の $x$ 軸，$y$ 軸ラベルは，label 引数で指定する。データフレームの列名を使用する場合は names() を指定する。別の名前にしたいときは，remane!()/rename() で列名を変更しておくか，直接 label=["a" "b" "c" "d"] のように名前を空白で区切って指定すればよい。

airquality3 = dropmissing(select(airquality, Not([:Month, :Day])));
cornerplot(Matrix(airquality3), label=names(airquality3), markersize=3, size=(600, 600))

作図レシピ

二軸グラフ

折れ線グラフと棒グラフを同時に描く例

using Plots, Plots.PlotMeasures
kion = [-3.0, -2.6, 2.5, 8.0, 15.7, 17.4, 21.7, 22.5, 19.3, 13.3, 3.9, -0.8];
kousuiryou = [86.0, 32.5, 39.0, 30.5, 29.5, 71.0, 31.5, 144.5, 108.5, 97.0, 82.0, 62.0];
tsuki = 1:12
#=
pyplot( grid=false,
        tick_direction=:out,
        xticks=1:12,
        right_margin=15mm)
=#
gr(     grid=false,
        tick_direction=:out,
        xticks=1:12,
        right_margin=15mm,
        fontfamily="IPAMincho",
        foreground_color_legend = nothing)
plot(   tsuki,
        kion,
        markershape=:circle,
        color=:red,
        ylabel="平均気温（℃）",
        label="平均気温",
        legend=:topleft)
bar!(   twinx(),
        tsuki,
        kousuiryou,
        alpha=0.3,
        ylabel="降水量（mm）",
        label="降水量",
        legend=:topright)

GKS: could not find font IPAMincho.ttf
GKS: glyph missing from current font: 24179
GKS: glyph missing from current font: 22343
GKS: glyph missing from current font: 27671
GKS: glyph missing from current font: 28201
GKS: glyph missing from current font: 65288
GKS: glyph missing from current font: 65289
GKS: glyph missing from current font: 24179
GKS: glyph missing from current font: 22343
GKS: glyph missing from current font: 27671
GKS: glyph missing from current font: 28201
GKS: glyph missing from current font: 65288
GKS: glyph missing from current font: 65289
GKS: glyph missing from current font: 24179
GKS: glyph missing from current font: 22343
GKS: glyph missing from current font: 27671
GKS: glyph missing from current font: 28201
GKS: invalid bitmap size
GKS: glyph missing from current font: 38477
GKS: glyph missing from current font: 27700
GKS: glyph missing from current font: 37327
GKS: glyph missing from current font: 65288
GKS: glyph missing from current font: 65289
GKS: glyph missing from current font: 38477
GKS: glyph missing from current font: 27700
GKS: glyph missing from current font: 37327
GKS: glyph missing from current font: 65288
GKS: glyph missing from current font: 65289
GKS: glyph missing from current font: 38477
GKS: glyph missing from current font: 27700
GKS: glyph missing from current font: 37327
GKS: invalid bitmap size

Andrews plot

外部リンク: StatsPlots Andrews プロットは，多変量を周期の異なる三角関数に割り当て，個体ごとに合成された曲線を描く。似た値を取る個体は同じような曲線になるので，全体的にどのような傾向をもつものがどれくらい存在するかを大まかに捉えることができる。

以下の使用例では，setosa と versicolor は似ているが，virginica はちょっと違うことがわかる。

しかし，この所見は間違っている。下の図の凡例が違っており（プログラムが不完全），茶色が virginica, 青が versicolor, 緑が setosa なので，他の分析手法で得られる「virginica と versicolor は似ているが，setosa はちょっと違う」というのが正解である。

using RCall
iris = rcopy(R"iris");

using StatsPlots
@df iris andrewsplot(:Species, cols(1:4), legend = :topleft, alpha=0.4)

include("andrewsgraph.jl");

y = Matrix(iris[:, 1:4])
# setosa: 1, blue, vercicolor: 2, red, virginica: 3, green
# col = transpose(vcat(fill(1, 50), fill(2, 50), fill(3, 50)))
col = repeat(1:3, inner=50)'
andrewsgraph(y, normalize=false, col=col)

andrewsgraph(y, normalize=true, col=col)

星座グラフ

include("constellationgraph.jl");

dat = Matrix(iris[:, 1:4])
col = vcat(fill(1, 50), fill(2, 50), fill(3, 50))
constellationgraph(dat, col=col)

サンフラワープロット

# import Pkg; Pkg.add("CategoricalArrays")

include("sunflowerplot.jl");

x = round.(3randn(500) .+ 10, digits=0);
y = round.(3randn(500) .+ 10, digits=0);

sunflowerplot(x, y, color=:gold, rotate=true)

p1 = sunflowerplot(iris.Sepal_Length[1:50], iris.Sepal_Width[1:50], color=:blue, r=0.07, rotate=true);
p2 = sunflowerplot(iris.Sepal_Length[51:100], iris.Sepal_Width[51:100], color=:green, r=0.07, initialize=false, rotate=true);
p3 = sunflowerplot(iris.Sepal_Length[101:150], iris.Sepal_Width[101:150], color=:red, r=0.07, initialize=false, rotate=true);

p3

レーダーチャート

include("radar.jl");

using RCall
swiss = rcopy(R"swiss");
first(swiss, 10)

10×6 DataFrame

Row	Fertility	Agriculture	Examination	Education	Catholic	Infant_Mortality
	Float64	Float64	Int64	Int64	Float64	Float64
1	80.2	17.0	15	12	9.96	22.2
2	83.1	45.1	6	9	84.84	22.2
3	92.5	39.7	5	5	93.4	20.2
4	85.8	36.5	12	7	33.77	20.3
5	76.9	43.5	17	15	5.16	20.6
6	76.1	35.3	9	7	90.57	26.6
7	83.8	70.2	16	7	92.85	23.6
8	92.4	67.8	14	8	97.16	24.9
9	82.4	53.3	12	7	97.67	21.0
10	82.9	45.2	16	13	91.38	24.4

test = swiss[1:5, 2:6]
test

5×5 DataFrame

Row	Agriculture	Examination	Education	Catholic	Infant_Mortality
	Float64	Int64	Int64	Float64	Float64
1	17.0	15	12	9.96	22.2
2	45.1	6	9	84.84	22.2
3	39.7	5	5	93.4	20.2
4	36.5	12	7	33.77	20.3
5	43.5	17	15	5.16	20.6

radar(test)

radar(test, col=[:black, :red, :green4, :blue, :brown])

radar(test, maxx=[50, 20, 20, 100, 23], normalize=false,
        col=[:black, :red, :green4, :blue, :brown])

radar(test, maxx=[50, 20, 20, 100, 23],
        minx=[10, 0, 0, 0, 20], normalize=false,
        col=[:black, :red, :green4, :blue, :brown])

radar(test, maxx=100, minx=0, normalize=false,
        col=[:black, :red, :green4, :blue, :brown])